Lidded Chests by Emily Short begins here.

Section 1 - The Chest and the Lid

A chest is a kind of container. A chest is always openable. A chest is usually fixed in place. The specification of a chest is "Represents a container with a separately implemented lid; the lid is itself a supporter."

A lid is a kind of supporter. A lid is part of every chest. The specification of a lid is "A supporter attached to a chest, which can only support things when the chest is closed."

Instead of examining a closed chest when something is on a lid (called the top) which is part of the chest:
	say "[The noun] is closed, and there [is/are list of things on the top] on top.";

Section 2 - Opening and Closing

Before opening a lid which is part of a chest (called the box):
	try opening the box instead.

Before closing a lid which is part of a chest (called the box):
	try closing the box instead.
	
Before opening a chest when something is on a lid (called the top) which is part of the noun:
	say "You'd have to remove [the list of things on the top] from the lid first." instead.
	
Instead of looking under a lid which is part of a chest (called the box):
	try opening the box.
	
Section 3 - Insertion and Support
	
Before putting something on a lid which is part of an open chest (called the box):
	say "(first closing [the box])[line break]";
	try closing the box.
	
Instead of putting something on a lid which is part of an open chest (called the box):
	say "[The box] would need to be closed first.";

Before inserting something into a lid which is part of a chest (called the box):
	try inserting the noun into the box instead.
	
Before putting something on a chest when a lid (called the top) is part of the second noun:
	try putting the noun on the top instead.	

Section 4 - Description in Rooms

After printing the name of a chest (called the box) while listing contents:
	if a lid (called the top) which supports something is part of the box, say " (on which [is/are list of things on the top])";

Lidded Chests ends here.

<Documentation>

Lidded Chests provides a simple kind, the chest, for containers with attached lids that are themselves supporters. We need not separately define the lids at all, since they are automatically provided, one per chest.

The behavior of chests is as follows: a chest cannot be opened when there is something on the lid; nothing may be put on a lid while the chest is open; "put on" and "put in" are directed to the correct portions of a chest. By default, a chest is fixed in place.